Time Intelligence trong Power BI: 7 hàm DAX cần biết

Time Intelligence trong Power BI là gì?

Time Intelligence là nhóm hàm DAX giúp bạn tính toán theo thời gian: lũy kế từ đầu tháng, quý, năm; so sánh với cùng kỳ năm trước hay tháng trước; tính trung bình trượt nhiều tháng. Thay vì lọc tay từng giai đoạn, bạn viết một measure và nó tự động đúng cho mọi tháng, quý, năm trên báo cáo.

Điều kiện bắt buộc: một bảng ngày chuẩn

Các hàm Time Intelligence chỉ chạy đúng khi mô hình có bảng ngày (Date table) đáp ứng 3 điều kiện:

Bạn có thể tạo nhanh bảng ngày bằng DAX:

Dim_Ngay =
ADDCOLUMNS (
    CALENDAR ( DATE ( 2024, 1, 1 ), DATE ( 2026, 12, 31 ) ),
    "Nam", YEAR ( [Date] ),
    "Thang", MONTH ( [Date] ),
    "TenThang", FORMAT ( [Date], "MM/yyyy" ),
    "Quy", "Q" & QUARTER ( [Date] )
)

Sau đó nối Dim_Ngay[Date] với cột ngày trong bảng Fact (ví dụ Fact_BanHang[NgayBan]) theo quan hệ 1 – nhiều. Nếu bạn chưa quen với bảng Fact, Dimension, hãy đọc trước bài Star Schema là gì? Cách xây mô hình dữ liệu chuẩn trong Power BI.

Toàn bộ ví dụ bên dưới dùng chung một measure gốc:

Doanh thu = SUM ( Fact_BanHang[ThanhTien] )

7 hàm DAX Time Intelligence Data Analyst cần biết

01 LŨY KẾ

1. TOTALYTD: lũy kế từ đầu năm

TOTALYTD cộng dồn giá trị từ ngày đầu năm đến ngày đang xét. Đây là hàm dùng nhiều nhất để theo dõi tiến độ so với kế hoạch năm.

Doanh thu YTD = TOTALYTD ( [Doanh thu], Dim_Ngay[Date] )

Nếu công ty dùng năm tài chính không trùng năm dương lịch (ví dụ kết thúc ngày 30/6), thêm tham số ngày kết thúc năm:

Doanh thu YTD (NTC) = TOTALYTD ( [Doanh thu], Dim_Ngay[Date], "6/30" )

02 LŨY KẾ

2. TOTALMTD và TOTALQTD: lũy kế từ đầu tháng, đầu quý

Cùng nguyên tắc với TOTALYTD nhưng tính từ ngày đầu tháng hoặc đầu quý. Rất hữu ích cho báo cáo theo dõi hàng ngày.

Doanh thu MTD = TOTALMTD ( [Doanh thu], Dim_Ngay[Date] )

Doanh thu QTD = TOTALQTD ( [Doanh thu], Dim_Ngay[Date] )

03 SO SÁNH

3. SAMEPERIODLASTYEAR: so sánh cùng kỳ năm trước

SAMEPERIODLASTYEAR dịch khoảng thời gian đang xét lùi đúng 1 năm. Kết hợp với CALCULATE và DIVIDE, bạn có ngay chỉ số tăng trưởng so với cùng kỳ (YoY):

Doanh thu cùng kỳ =
CALCULATE ( [Doanh thu], SAMEPERIODLASTYEAR ( Dim_Ngay[Date] ) )

Tăng trưởng YoY % =
DIVIDE ( [Doanh thu] - [Doanh thu cùng kỳ], [Doanh thu cùng kỳ] )

Dùng DIVIDE thay cho phép chia “/” để tránh lỗi khi năm trước chưa có dữ liệu (chia cho 0).

04 SO SÁNH

4. DATEADD: dịch linh hoạt theo ngày, tháng, quý, năm

DATEADD cho phép dịch khoảng thời gian theo số đơn vị bạn muốn. Cách dùng phổ biến nhất là so sánh với tháng trước (MoM):

Doanh thu tháng trước =
CALCULATE ( [Doanh thu], DATEADD ( Dim_Ngay[Date], -1, MONTH ) )

Tăng trưởng MoM % =
DIVIDE ( [Doanh thu] - [Doanh thu tháng trước], [Doanh thu tháng trước] )

Thay MONTH bằng DAY, QUARTER hoặc YEAR để đổi đơn vị; DATEADD(Dim_Ngay[Date], -1, YEAR) cho kết quả tương tự SAMEPERIODLASTYEAR.

05 SO SÁNH

5. PARALLELPERIOD: lấy trọn cả giai đoạn trước

Khác với DATEADD, PARALLELPERIOD trả về trọn vẹn tháng, quý hoặc năm trước, bất kể bạn đang xem một ngày hay một tháng. Dùng khi cần hiển thị tổng cả năm trước làm mốc tham chiếu:

Doanh thu cả năm trước =
CALCULATE ( [Doanh thu], PARALLELPERIOD ( Dim_Ngay[Date], -1, YEAR ) )

06 KỲ TRƯỚC

6. PREVIOUSMONTH: doanh thu của tháng liền trước

PREVIOUSMONTH trả về toàn bộ các ngày của tháng trước so với ngày đầu tiên trong bối cảnh hiện tại. Tương tự có PREVIOUSQUARTER, PREVIOUSYEAR, NEXTMONTH…

Doanh thu PM =
CALCULATE ( [Doanh thu], PREVIOUSMONTH ( Dim_Ngay[Date] ) )

07 XU HƯỚNG

7. DATESINPERIOD: tổng và trung bình trượt (rolling)

DATESINPERIOD lấy một khoảng thời gian tính lùi từ một mốc. Đây là cách tính doanh thu 3 tháng hoặc 12 tháng gần nhất, giúp làm mượt biến động theo mùa vụ:

Doanh thu 3 tháng gần nhất =
CALCULATE (
    [Doanh thu],
    DATESINPERIOD ( Dim_Ngay[Date], MAX ( Dim_Ngay[Date] ), -3, MONTH )
)

TB trượt 3 tháng = DIVIDE ( [Doanh thu 3 tháng gần nhất], 3 )

Bảng tổng hợp: câu hỏi nào dùng hàm nào?

Những lỗi thường gặp khi dùng Time Intelligence

• Không có bảng ngày riêng hoặc chưa Mark as date table: các hàm trả về trống hoặc sai.
• Bảng ngày bị thiếu ngày: tạo bảng ngày từ cột ngày của bảng Fact khiến những ngày không có giao dịch bị mất. Hãy dùng CALENDAR hoặc CALENDARAUTO.
• Dùng cột ngày của bảng Fact trên biểu đồ: bộ lọc không truyền đúng, số cùng kỳ bị lệch.
• So sánh tháng hiện tại chưa kết thúc với cả tháng trước: tăng trưởng hiển thị âm dù kinh doanh vẫn tốt. Nên giới hạn so sánh đến ngày có dữ liệu mới nhất.
• Dùng phép chia “/” thay vì DIVIDE: báo cáo hiện lỗi Infinity hoặc NaN khi mẫu số bằng 0.
• Nhầm DATEADD với PARALLELPERIOD: DATEADD dịch đúng khoảng đang xem, PARALLELPERIOD lấy trọn cả giai đoạn.

Câu hỏi thường gặp (FAQ)

Kết luận

Thông tin tác giả